\ --- morse/base.fs -------------------------
\ 2011-10-26  EW
\ 2011-11-02  CS
\ arduino duemilanove + danger shield
\ morse code stuff
\ (Potsdam/Augsburg/Oberhausen)

\ make marker loads:
\   lib/misc.frt
\   lib/bitnames.frt
\   lib/ans94/marker.frt
\   .../devices/atmega328p/atmega328p.frt

marker --base--
decimal

PORTB 2 portpin: sw1
PORTB 3 portpin: sw2
PORTB 4 portpin: sw3

PORTD 5 portpin: led1
PORTD 6 portpin: led2

PORTD 3 portpin: bz

PORTC 2 portpin: sl1
PORTC 1 portpin: sl2
PORTC 0 portpin: sl3

PORTC 3 portpin: photocell
PORTC 4 portpin: thermometer
PORTC 5 portpin: knocksensor

PORTD 4 portpin: sr_in
PORTD 7 portpin: sr_oe \ output enable
PORTB 0 portpin: sr_cl

\ Piepser
\ 2 ms T_period =^= 500 Hz
: buzz ( cycles -- )
  0 ?do bz low 1ms bz high 1ms loop
;
: gap  ( cycles -- )
  0 ?do bz high 1ms bz high 1ms loop
;
: blink ( cycles -- )
  led1 high
  0 ?do  1ms 1ms 1ms loop
  led1 low
;

Edefer transmit
: piepser   ['] buzz  is transmit ;
: blinker   ['] blink is transmit ;

decimal
: kurz    50 transmit 50 gap ;
: lang   150 transmit 50 gap ;
: Zend   100 gap ;   \ Pause zwischen Zeichen
: Wend   300 gap ;   \ Pause zwischen Worten

: init
  led1 pin_output led1 low
  led2 pin_output led2 low
  bz   pin_output

  piepser
;