\ 2011-07-13  adv9_1.fs

include lib/misc.frt
include lib/bitnames.frt
include lib/ans94/marker.frt
include atmega32.frt

marker --start--

PORTC 2 portpin: _rfm12 \ requires -jtag
PORTB 5 portpin: _mosi
PORTB 6 portpin: _miso
PORTB 7 portpin: _clk

\ /ss +spi -spi ><spi
include spi.fs
\ +rfm12 rfm12.init
\ >wc wc? w? >w <w w.status
include rfm12.fs

\ --- rfm12 ---
: rfm12.rx   $82d9 >wc ;
: rfm12.off  $8201 >wc ;

: rfm12.rx.all \ no sync
  -jtag
  +spi +rfm12
  rfm12.init w.status cr
  rfm12.rx
  $ca87 >wc \ ???
  hex
  begin
    <w 2 u0.r space
  key? until
  key drop
  rfm12.off
;

: rfm12.tx.on  ( -- )  $8238    >wc ;
: rfm12.tx.off ( -- )  $8208 w? >wc ;
: init
  -jtag
  +spi +rfm12
  rfm12.init
  w.status cr
;

\ send a data frame
: rfm12.tx.data ( xN .. x1 N -- )
  rfm12.tx.on
  $aa >w \ sync pattern
  $aa >w
  $aa >w
  
  $2d >w \ magic bytes
  $d4 >w

  $10 0 do     \ payload data
    i $30 + $b800 + w? >wc
  loop

  $b8aa w? >wc \ sync pattern
  $b8aa w? >wc
  $b8aa w? >wc

  rfm12.tx.off
;

\ receive a data frame
: rfm12.rx.clearfifo $ca81 >wc $ca83 >wc ;
: rfm12.rx.sync      $82c8 >wc ;
: rfm12.rx.data ( n -- )
  rfm12.rx.sync
  rfm12.rx.clearfifo
  hex
  w?
  \ read n Bytes
  ( n ) 0 do <w 2 u0.r space loop
;